【毕业论文】如何进行稳健性检验和异质性分析？

非诚勿扰孟非

0. 前情提要

在前边，我们已经完成了文章的基础实证部分。但是，我们知道只是进行了基础回归的文章是很缺乏说服力的，因此我们后续还需要有大量的内容，对实证结果进行完善，使得结果更加具有可信度。
和刚开始接触时进行了序列相关、异方差、多重共线性等各种修正方式不同，一篇实证论文通常并不很注重这些。又或者说，这些内容有些过于简单以至于不至于被单独拿出来说。相比之下，更加常见和普遍的内容为，稳健性检验和异质性分析。
这两个部分通常为文章实在没有什么值得拿出来说，但是总归又要说点什么的部分。接下来使用一个例子数字金融发展（x）对女性地位（y）的影响进行介绍。在此需要说明的是，女性地位数据来自于CFPS微观数据库，地区数字金融发展数据来自北京大学数字普惠金融指数。
1. 理论分析

在知道应该需要怎么做之前，我们还需要知道的是我们为什么需要这样做？以及这样做到底有什么样的意义？
2.1 稳健性检验

个人的理解是，所谓的稳健性检验，是将比较重要的变量（一般为核心的X或者Y）用具有同类经济含义的变量替换后进行的回归检验。其存在最主要的作用是为了避免一些数据统计所造成的结果的偶然性。
意思是，如果我只有一种方式衡量变量，那么变量之间显著的关系，可能仅仅只是因为某些”统计数据的偶然“所造成的。但是我使用不同的指标来衡量一个变量（比如说此处使用四种人们对女性态度的指标，以及四种衡量数字金融发展水平的方式），所得到的结果依然是显著的，那么就可以排除这种情况的，认为结果具有一定的稳健性。
2.2 异质性分析

异质性分析的目的在于，探究我们所提出的机制，在不同的样本或群体之间的传导是否存在差异。一方面，有助于我们为我们后文的政策意见和前文的实际意义提供了一些理论支持。但是个人认为更重要的是，通过异质性分析，观测实证结果与理论结果是否相符合，这样有助于证明我们理论机制的正确性。
2. 具体操作

稳健性检验和异质性分析，在最开始接触的时候可能认为是比较高端大气的名词。但是在理解之后就会发现，这些所谓的术语，其实叫做换变量回归和换样本回归可能更接地气。
2.0 数据介绍

在实证的开始前，首先我们需要了解使用的数据，不然会出现结果看得云里雾里的情况。此处使用的数据来源在前文已经介绍，至于怎么将两个数据集进行合并，并且对数据进行清洗，这个有空的时候再单独进行介绍。现在需要知道的就是，手里存在这样的一个数据，数据中包含以下变量：



样例变量列表

其中：

• 被解释变量（女性地位）：H_1~H_4等H打头的变量，衡量样本个体对女性的一些看法
  
• 解释变量（数字金融）：l_index开头的变量，衡量所在地区的数字金融发展水平
  
• 控制变量：可能影响女性地位的其他变量，除解释和被解释变量外的变量
  

use "data_example.dta", clear                   // 数据导入

global Y H_1                                    // 被解释变量
global X l_index_all                            // 解释变量
global X_CON age married size w_fincome w_fsave // 控制变量集

需要说明的是，虽然H_1-H_4均为被解释变量，但是通常我们只选择一个变量作为主要被解释变量（此处选择，H_1），其余的变量则作为用于稳健性检验的被解释变量（即此处的H_2-H_4），核心解释变量同理。故此处定义的被解释变量为H_1，核心解释变量为l_index_all

2.1 基础回归

有了基础回归作为对比，才好对稳健性和异质性进行进一步的分析。首先按照上一章所讲，进行基础回归。
reg $Y $X $X_CON可以得到如图所示回归结果：



基础回归结果

不难看出的是，显著性水平为0.000，且系数为负数。说明基础回归结果较好，数字金融的发展会提高女性的社会地位（因为该地区的人更不赞同女性应该以家庭为主的观点）。

基础回归重点关注：显著性水平是否显著，回归系数符号是否符合预期。具体操作和读法见上一章。

2.2 稳健性检验

此后我们需要使用不同的变量来衡量原本的x和y检验结果的稳健性。具体的代码为：
global x_robust l_index_all l_index_01 l_index_02 l_index_03    // x的可替代变量
local vars $x_robust        // 定义循环变量 x_robust
foreach x of local vars{    // 进行循环
    reg $Y `x' $X_CON , r   // 循环的时候替换x
}运行完此段程序过后，即可得到使用x_robust中所有变量（此处共四个）进行回归的结果（因此此处会得到四个回归结果），并按照正常基础回归结果的地方分析结果即可。需要注意的是由于此处涉及循环，因此需复制到do文件中运行，不能直接在命令窗口粘贴。
此外，为使得结果更加具有可读性，同时便于写文章的时候进行编辑，我们通常需要对所得结果进行再整理或者导出到文档，具体的代码为：
global x_robust l_index_all l_index_01 l_index_02 l_index_03   
cap erase "xrobust.txt"     // 删除原有的txt文件 -- 暂时可以不管
local vars $x_robust        

foreach x of local vars{    // 进行循环
    qui reg $Y `x' $X_CON , r   
    qui outreg2 using "xrobust.xls", append bdec(3) tdec(2) ctitle(`y') // 导出到excel
    est store xrobust_`x'   // 记录结果
}

// 记录结果的展示 -- 暂时可以不管
esttab xrobust_*, replace   ///
    nogap compress b(%6.3f) s(N r2_a) se  ///   
    star(* 0.1 ** 0.05 *** 0.01)          ///
    addnotes("*** 1% ** 5% * 10%")

drop _est*  // 为避免重复，删除计量的结果运行完此代码过后，我们可以得到一个所有的x_roubst变量对y回归结果的汇总表：



x的稳健性检验

其中应该重点关注的部分为红色框内部分，理想的结果为：

• 所有的结果均三星显著，且符号与理论预期相符（完美结果）
  
• 大部分（不要求所有）结果显著（不要求三星），且符号基本与理论预期相符（能用结果）
  

对比上述要求不难看出，上述结果虽全三星显著，但是第四列（index_03）回归系数与理论预期不相符。这样的结果虽算不上完美，但是也能算差强人意勉强能够接受。先占一个坑，如果结果不好该怎么调整，后边争取单独写一篇来讲

同理，运行下边这段代码，我们可以得到y的稳健性回归结果。
global y_robust H_1 H_2 H_3 H_4 // 稳健性检验 - y

cap erase "yrobust.txt"
local vars $y_robust
foreach y of local vars{
    qui reg `y' $X $X_CON , r
    qui outreg2 using "yrobust.xls", append bdec(3) tdec(2) ctitle(`y')
    est store yrobust_`y'
}

esttab yrobust_*, replace   ///
    nogap compress b(%6.3f) s(N r2_a) se  ///
    star(* 0.1 ** 0.05 *** 0.01)          ///
    addnotes("*** 1% ** 5% * 10%")
drop _est*


y的稳健性检验

这个也是个差强人意的结果，三个变量的结果是显著的，但显著的变量的系数均和理论预期相符。

2.3 异质性分析

所谓的异质性分析，其实就是，对不同的分类群体进行分组回归，并且对比分组回归的结果。在开始分组回归之前，我们首先需要对样本进行分组。常见的分组方式有包括，根据收入、性别、年龄（个体）；或是东中西、南北、是否沿海、是否直辖、是否少数民族（地区）等，而分类的方式则可以参照我的另一篇笔记。
sort w_fsave                // 按照受教育水平排序(升序)
gen group_fsave = group(4)  // 按照储蓄水平四等分运行此代码，可以将样本按照储蓄水平进行四等分，并生成group_fsave变量，其中group_fsave取值越低表明个体储蓄越少。
和稳健性检验类似，我们这里使用循环加条件语句的方式进行份样本的回归，并将所得的回归结果进行储存和导出操作。
cap erase "groupsave.txt"
forvalues i = 1/4{
    qui reg $Y $X $X_CON if group_fsave == `i', r   // if 后为对满足条件的样本进行回归
    qui outreg2 using "groupsave.xls", append bdec(3) tdec(2) ctitle(`y')
    est store groupsave_`i'
}

esttab groupsave_*, replace ///
    nogap compress b(%6.3f) s(N r2_a) se  ///
    star(* 0.1 ** 0.05 *** 0.01)          ///
    addnotes("*** 1% ** 5% * 10%")
drop _est*所得到的结果为：



异质性分析

在这个所得结果中，我们重点需要关注两方面的内容：

• 核心解释变量的显著性（越显著越好）
  
• 核心解释变量的系数大小（符合理论预期为好）
  

注意：基础回归重点关注系数的符号，而异质性分析则需要关注系数的大小。

而对结果的分析则需要根据相应的理论进行，并没有一个较为合适的普适的“好结果”。就此处而言，异质性分析的结果较为理想（指符合理论预期），具体表现在：对于存款水平越高的家庭（列数越靠后，存款水平越高，从1-4），数字金融发展对女性歧视的抑制作用越明显，这显然是符合理论预期的。
3. 完整代码

最后，附上完整的do文件代码，需要样例数据可私戳。
use "robust_example.dta", clear                 // 数据导入

global Y H_1                                    // 被解释变量
global X l_index_all                            // 解释变量
global X_CON age married size w_fincome w_fsave // 控制变量集   

* --- 基础回归

reg $Y $X $X_CON

* --- 稳健性检验

global x_robust l_index_all l_index_01 l_index_02 l_index_03    // x的可替代变量
cap erase "xrobust.txt"     // 删除原有的txt文件 -- 暂时可以不管
local vars $x_robust        // 定义循环变量 x_robust
foreach x of local vars{    // 进行循环
    qui reg $Y `x' $X_CON , r   // 循环的时候替换x
    qui outreg2 using "xrobust.xls", append bdec(3) tdec(2) ctitle(`y') // 导出到excel
    est store xrobust_`x'   // 记录结果
}

// 记录结果的展示
esttab xrobust_*, replace   ///
    nogap compress b(%6.3f) s(N r2_a) se  ///   
    star(* 0.1 ** 0.05 *** 0.01)          ///
    addnotes("*** 1% ** 5% * 10%")

drop _est*

global y_robust H_1 H_2 H_3 H_4 // 稳健性检验 - y

cap erase "yrobust.txt"
local vars $y_robust
foreach y of local vars{
    qui reg `y' $X $X_CON , r
    qui outreg2 using "yrobust.xls", append bdec(3) tdec(2) ctitle(`y')
    est store yrobust_`y'
}

esttab yrobust_*, replace   ///
    nogap compress b(%6.3f) s(N r2_a) se  ///
    star(* 0.1 ** 0.05 *** 0.01)          ///
    addnotes("*** 1% ** 5% * 10%")
drop _est*

* --- 异质性分析

sort w_fsave                // 按照受教育水平排序(升序)
gen group_fsave = group(4)  // 将受教育水平四等分

cap erase "groupsave.txt"
forvalues i = 1/4{
    qui reg $Y $X $X_CON if group_fsave == `i', r
    qui outreg2 using "groupsave.xls", append bdec(3) tdec(2) ctitle(`y')
    est store groupsave_`i'
}

esttab groupsave_*, replace ///
    nogap compress b(%6.3f) s(N r2_a) se  ///
    star(* 0.1 ** 0.05 *** 0.01)          ///
    addnotes("*** 1% ** 5% * 10%")
drop _est*<hr/>2.25更新：上传样例数据附件
data_example.dta
1.3M
· 百度网盘



原文地址：https://zhuanlan.zhihu.com/p/428282967